10
Jun 11

Sparql’ing Natural Gas Economics

IEA released a special report on natural gas this week intriguingly titled “Are we entering a golden age of gas?”.
The IEA’s “Golden Age of Gas Scenario” (GAS scenario) entertains a few assumptions relating to more aggressive adoption of natural gas in the world, expecting gas demand to grow by 65% in the next 25 years.
The assumptions driving the adoption are:

  • rapid demand growth in BRIC countries, especially China;
  • mothballed nuclear (immediate in Japan and Germany);
  • production of unconventional gas in the US and China;
  • growing LNG market;
  • lower (than projected before) gas prices due more aggressive conventional and shale resource development

Detailed scenarios and convincing projections are IEA speciality. It would be interesting though to try to recreate some of the analyses done by IEA using SPARQL and Enipedia’s data on natural gas and see if we can arrive at similar intuitions as detailed in the IEA report.

Note that Enipedia’s data on natural gas is obtained mostly from BP’s World Statistical Energy Review but also includes numerous other sources, such as CIA Factbook, Wikipedia, IEA, US EIA and others.

China

Most of the Chinese power generation is coal based, due to abundance of local resources. Currently Chinese produce around 3’000Mt annually from their proven reserves of 115’000Mt ensuring almost 40 years of future consumption. The low prices of coal in China make natural gas a poor competitor in the power generation area. The query below aggregating Chinese power plant data in Enipedia indicates that around 75% of power generation emits more than 600Kg of CO2 per MWh produced. The 600kg/MWh benchmark can be used to indicate a coal based generator, inferring around 80% of generation is coal based. The CIA factbook also confirms that 80% of power generation on China is in fact fossil fuel based.

select ?Category (sum(?out / 3.6e15) as ?TotalAnnualOutputTWh) where {
{
    select * where {
    ?plant rdf:type cat:Powerplant;
       prop:Country a:China ;
       prop:Energyoutput-23J ?out ;
       prop:Intensity-23kg ?IntensityKgMWh .
    LET (?Category := "MoreThan600KgCO2perMWh")
    Filter(?IntensityKgMWh > 600)
    }
} UNION {
    select * where {
    ?plant rdf:type cat:Powerplant;
       prop:Country a:China ;
       prop:Energyoutput-23J ?out ;
       prop:Intensity-23kg ?IntensityKgMWh .
    LET (?Category := "LessThan600KgCO2perMWh")
    Filter(?IntensityKgMWh < 600)
    }
}
} group by ?Category

Result

The IEA scenario justifies gas growth in China by assuming a proactive government policy to diversify fuel sources and clean up power generation portfolio. Interestingly, given the premium gas prices in Asia, gas based generation becomes attractive (on the basis of levelized cost of electricity) only at CO2 cost of around 100 USD/T. It could be interesting to increase the weight of nuclear and wind alternatives in China too. But given the rapid expansion of Chinese urban sprawl, it is reasonable to expect gas growth due to factors besides cost: quick installation (2 years for CCGT), flexibility of cycle making gas attractive in combination with wind, and relatively low emissions.

Japan

A more immediate effect on the natural gas demand comes from Japan, where 30% of power generation is nuclear and due to recent unfortunate events might have to be replaced by gas based generation. (Try to run the first query by replacing China with Japan in lines 6 and 15.) Currently Japan imports around 100Bcm of natural gas annually. The following query calculates the required amount of gas to replace the current 30% of nuclear capacity by CCGT, assuming 6000BTU/kWh heat rate.

select
(sum(?out) as ?OutputMWh)
(sum(?out) * 0.3 as ?NuclearOutputMwh)
(sum(?out) * 0.3 * 6e6 as ?NuclearOutputReplacedByGasBtu)
(sum(?out) * 0.3 * 6e6 / 35e12 as ?GasBcm)
where {
?plant rdf:type cat:Powerplant;
       prop:Country a:Japan ;
       prop:Annual_Energyoutput_MWh ?out .
}

Result
The result is around 53Bcm of natural gas annually or 50% of current Japanese imports and 18% of worlds total LNG market. Of course the nuclear generation will not be phased out completely but it is valuable to see the extent of such decision.

Unconventional Gas

select
    (sum(?consumption) / 1e9 as ?ConsumptionBcm)
    (sum(?production) / 1e9 as ?ProductionBcm)
    (sum(?conventionalResources) / 1e12 as ?ConventionalResourcesTcm)
    (sum(?shaleResources) / 1e12 as ?ShaleResourcesTcm)
    (?ConventionalResourcesTcm + ?ShaleResourcesTcm as ?TotalResourcesTcm)
    (?ConventionalResourcesTcm * 1e3 / ?ProductionBcm as ?ConventionalProductionYears)
    (?ShaleResourcesTcm * 1e3 / ?ProductionBcm as ?ShaleProductionYears)
    (?ConventionalProductionYears + ?ShaleProductionYears as ?TotalProductionYears)
where {
    ?country prop:NaturalGasConsumption-23m3 ?consumption;
         prop:NaturalGasProduction-23m3 ?production;
         prop:NaturalGasProvenResources-23m3 ?conventionalResources;
         prop:TechnicallyRecoverableShaleGasResources-23m3 ?shaleResources ;
}

Result
Natural gas resource calculations (based primarily on BP data) above reveal that the shale gas resources available worldwide already match the conventional resources. Both amount to around 190Tcm and provide 60 years of production at current rates (R/P ratio). The interesting property of shale gas resources is their distribution. While conventional gas resources are concentrated and stranded in remote locations far away from the end consumer (Siberia or Sahara), shale resources are distributed relatively more evenly and closer to the growing markets.

The following query reveals the top 20 countries with most conventional resources:

select ?name
    (?conventionalResources / 1e12 as ?conventionalResourcesTcm)
where  {
    ?country rdfs:label ?name;
                prop:NaturalGasProvenResources-23m3 ?conventionalResources .
} order by desc(?conventionalResourcesTcm) limit 20

Result

The chart puts Russia, Iran, Qatar, Turkmenistan and Saudi Arabia as the primary donors of natural gas reserves. Comparing that to the distribution of shale gas reserves (see query and chart below) - the owners here are the primary consumers too. China, Argentina, Mexico, Brazil and South Africa are the growing economies soon to benefit from the improvements in shale gas technology and resulting domestic resources.

select
    ?name
    (?shaleResources / 1e12 as ?shaleResourcesTcm)
where  {
    ?country rdfs:label ?name;
                prop:TechnicallyRecoverableShaleGasResources-23m3 ?shaleResources .
} order by desc(?shaleResourcesTcm) limit 20

Result

For US - the owner of second largest shale resource - it could mean turning into natural gas exporter.
For countries like France, Poland and the Eastern European block it will mean more diversified supply and lower import costs from Russia.

Despite the environmental concerns, for the EU, shale gas could translate into more diversified and secure supply of natural gas.

Pricing

As much as shale gas could impact the pricing mechanisms leading to more gas-indexed prices, the current natural gas market is still primarily tied to oil prices. Globally, around one-fifth of gas supply is oil-linked - primarily in South Korea, Japan and continental Europe (IEA). A third of world's gas supply is based on gas-index prices (called gas-to-gas), mechanism prevalent primarity in the US, UK and Australia. In order to be able to index long-term contract prices to gas futures prices, a liquid gas futures market is required. Henry Hub in the US and National Balancing Point in the UK provide pricing benchmarks for the two markets.

The price charts below indicate that a stronger relation between more liquid US and UK gas market prices. The continental European and Japanese prices (indicative of South-East Asian market) display a stronger link to rising oil prices.

Despite that in 2010 the UK-US price spreads widened as the natural gas from UK was redirected to higher price areas in the continental Europe. It is likely that in the medium term a similar situation could turn the US into gas exporter to South-East Asia, as the price spread has recently shot up to 6-7USD/MMBtu. IEA explains that economic slowdown and local shale discoveries in the US have a temporary glut that already redirected US destined LNG to Europe and Asia. Even the destination-restricted LNG cargoes were unloaded in the US just to be loaded back again and sent to higher price destinations.

IEA also questions the emergence of gas-to-gas based pricing mechanisms in the continental Europe, where 75% of natural gas is still linked to high oil prices. The query below lists the EU's gas suppliers and annual volumes.

select ?from (sum(?volume  / 1e9) as ?ImportVolumeBcm) where {
   ?flow prop:GasFlowTo ?to ;
         prop:GasFlowVolume-23m3 ?volume ;
         prop:GasFlowFrom ?from .
   ?to a cat:EUMember .
   Filter(Not exists {?from a cat:EUMember} ) .
} group by ?from order by desc(?ImportVolumeBcm)

Result

Russia dominates EU's natural gas imports, which to a great extent explains the oil-linked pricing that is beneficial to the Russian national oil and gas companies. We will look at the security of gas supply in relation to pricing mechanisms in more detail next.

Security of Supply

Asia

Asia has relatively diversified supply but the significantly higher natural gas prices reflect higher costs of transport and the monopoly situation in downstream (non-liberalised market) where the gas distribution companies can pass the high gas prices to consumers. For example, government monopoly KOGAS in South Korea controls all LNG imports and thus - prices. LNG terminals in Japan are owned by utilities and power generators. The query below reveals that 40% of natural gas based generation is owned by Tepco who is also perhaps able to pass the higher costs to the end customer. In Japan heating is frequently oil-based or electrical, thus oil price is the real opportunity cost for the gas consumer (which is NOT the case in Europe).

select ?company ?totalCompanyOutputMWh ?totalGasOutputMWh (?totalCompanyOutputMWh / ?totalGasOutputMWh as ?pctOutput) where {
{
select ?company (sum(?output) / 3.6e9 as ?totalCompanyOutputMWh) where {
?plant a cat:Powerplant ;
   prop:Country a:Japan ;
   prop:Intensity-23kg ?intensity ;
   prop:Energyoutput-23J ?output ;
   prop:Ownercompany ?company .
Filter (?intensity < 600 && ?intensity > 200) .
} group by ?company order by desc(?totalOutputMWh)
}
{
select (sum(?output) / 3.6e9 as ?totalGasOutputMWh) where {
?plant a cat:Powerplant ;
   prop:Country a:Japan ;
   prop:Intensity-23kg ?intensity ;
   prop:Energyoutput-23J ?output ;
   prop:Ownercompany ?company .
Filter (?intensity < 600 && ?intensity > 200) .
}
}
} order by desc(?pctOutput) limit 10

Result

Europe

As mentioned before, 3/4 of imported natural gas volume in the EU is also oil-price linked, while - unlike in Japan - the gas competition in Europe is not oil but mostly coal, nuclear and European gas. Gradual liberalisation of European gas markets has pushed the gas consumers to demand more flexibility and gas-to-gas based contracts (indexed to gas prices observed at European gas hubs). Despite that major exporters (Russia) refuse to change their lucrative pricing schemes. Herfindahl–Hirschman index calculated on the exporter shares can be used to assess the bargaining power of the importing countries and explain the pricing mechanisms.

Herfindahl–Hirschman Index as Proxy for Security Of Supply

The Herfindahl–Hirschman Index (HHI) is a measure of the size of firms in relation to the industry and an indicator of the amount of competition among them. Named after economists Orris C. Herfindahl and Albert O. Hirschman, it is an economic concept widely applied in competition law, antitrust and also technology management. It is defined as the sum of the squares of the market shares of the largest firms within the industry, where the market shares are expressed as fractions. The result is proportional to the average market share, weighted by market share. As such, it can range from 0 to 1.0, moving from a huge number of very small firms to a single monopolistic producer. Increases in the Herfindahl index generally indicate a decrease in competition and an increase of market power, whereas decreases indicate the opposite.

Here we're using HHI as a proxy to measure security of natural gas supply. Instead of calculating the market shares of companies, we calculate the shares of gas suppliers to a country. The higher the HHI score, the more the importing country is dependent on its suppliers, and the higher the monopoly power of the suppliers.

The following (more advanced) query will return a list of countries that have gas import HHI over 0.7, which is a good cut-off point for assuming high monopoly power of the supplier.

select ?to ?from ((?volume / 1e9) as ?volumeBcm) ?HHI  where {
?flow prop:GasFlowTo ?to ;
       prop:GasFlowFrom ?from ;
       prop:GasFlowVolume-23m3 ?volume .
{ select ?to (sum(?shareOfSupplySqr) as ?HHI) where {
{ select ?to ?from ((?volume  / 1e9) as ?volumeBcm) ?totalVolumeBcm (?volumeBcm / ?totalVolumeBcm as ?shareOfSupply) (?shareOfSupply * ?shareOfSupply as ?shareOfSupplySqr) where {
 ?flow prop:GasFlowTo ?to ;
       prop:GasFlowFrom ?from ;
       prop:GasFlowVolume-23m3 ?volume .
 ?from rdfs:label ?fromName .
 ?to rdfs:label ?toName .
 {
  select ?to (sum(?volume  / 1e9) as ?totalVolumeBcm) where {
   ?flow prop:GasFlowTo ?to ;
         prop:GasFlowVolume-23m3 ?volume .
   } group by ?to
 }
}
}
} group by ?to
}
filter (?HHI > 0.7)
} order by desc(?HHI) ?to ?from

Result

The most dependent seem to be the Eastern European countries from the ex-Soviet block, plus Finland having Russia as the sole supplier of natural gas. This explains the fact that a big share of European gas still is and probably will be linked to high oil prices, unless the sources of supply are diversified. Growth in shale gas and LNG expansion seem to be reasonable to expect in the immediate future as Europe diversifies its suppliers in order to move towards more competitive gas prices.

Another group of countries in a similar situation are Syria, Lebanon, Israel and Jordan. They have Egypt as their sole supplier.

The following query will return a list of countries with HHI less than 0.3 - meaning a well diversified supply:

select ?to ?from ((?volume / 1e9) as ?volumeBcm) ?HHI  where {
?flow prop:GasFlowTo ?to ;
       prop:GasFlowFrom ?from ;
       prop:GasFlowVolume-23m3 ?volume .
{ select ?to (sum(?shareOfSupplySqr) as ?HHI) where {
{ select ?to ?from ((?volume  / 1e9) as ?volumeBcm) ?totalVolumeBcm (?volumeBcm / ?totalVolumeBcm as ?shareOfSupply) (?shareOfSupply * ?shareOfSupply as ?shareOfSupplySqr) where {
 ?flow prop:GasFlowTo ?to ;
       prop:GasFlowFrom ?from ;
       prop:GasFlowVolume-23m3 ?volume .
 ?from rdfs:label ?fromName .
 ?to rdfs:label ?toName .
 {
  select ?to (sum(?volume  / 1e9) as ?totalVolumeBcm) where {
   ?flow prop:GasFlowTo ?to ;
         prop:GasFlowVolume-23m3 ?volume .
   } group by ?to
 }
}
}
} group by ?to
}
filter (?HHI < 0.3)
} order by desc(?HHI) ?to ?from

Result

Japan, South Korea in Asia top the list, having the most diversified sources of supply, and perhaps the highest security of supply. Despite that their gas prices are significantly higher, which as already discussed is more due to non-liberalized national gas markets, rather than un-diversified supply.

In Europe countries with low HHI are countries with LNG terminals (Belgium, France, Spain) or geographically situated closer to suppliers (Italy). HHI can be interpreted as a measure of diversification, it can also be used as a heuristic for country's trading potential - potential to become a gas trading hub. In conjunction with storage, other infrastructure investments and the right policies countries like Belgium, Netherlands or Austria have the potential to become the trading hubs of continental Europe such as HenryHub in the US, or NBP in the UK.


Hopefully this rather quick glimpse at the world's gas markets and the arguments used in the new IEA's report also managed to demonstrate how to use SPARQL to analyse Enipedia's energy data.

P.S Enipedia's public SPARQL endpoint is available at: http://enipedia.tudelft.nl/wiki/Special:SparqlExtension

Happy Sparqling!

keywords: ,

Leave a Reply